Definition von VALUE

Mit dem VALUE-Operator können Daten in einer internen Tabelle (itab) gelesen, Daten in einen Arbeitsbereich (wa) oder eine Struktur eingegeben (kann zur Zuweisung fester Daten verwendet werden) und zum Erstellen und Lesen von itabs verwendet werden.

report zae_value.

" structure için types tanımı oluşturulur
types: begin of ty_value,
         name type string,
         role type string,
       end of ty_value.

" eğer inline olarak structure oluşturacaksak aşğıdaki gibi
" data kullanımı ile value kullanılarak değer atanır.
data(wa) = VALUE ty_value( name = 'Ahmet' role ='Developer' ).

" wa içeriğini görmek için aşağıdaki class kullanılır, sadece demo için
cl_demo_output=>display( wa ).

Im obigen Beispiel haben wir eine Typendefinition vorbereitet. Dann haben wir den Arbeitsbereich (wa) inline definiert und ihm mit VALUE Werte zugewiesen. Nach dem VALUE-Befehl haben wir ty_value angegeben, um anzuzeigen, dass unsere wa-Struktur die Struktur von ty_value haben soll. Innerhalb der Klammern haben wir Daten für die Felder „name“ und „role“ eingegeben, die wir als Typen definiert haben. Mit der Klasse cl_demo_output haben wir die Anzeige des wa-Inhalts direkt auf dem Bildschirm ermöglicht, ohne in den Debug-Modus zu wechseln.

Da wir den Arbeitsbereich (wa) im obigen Beispiel inline definiert haben, haben wir tatsächlich festgelegt, wie dieser wa-Typ nach VALUE sein soll. Hätten wir den wa dort definiert, wo wir in unserem Programm DATA-Definitionen vornehmen, wäre seine Verwendung etwas anders.

Schauen wir uns den folgenden Code an und geben Erklärungen dazu.

report zae_value.

types: begin of ty_value,
         name type string,
         role type string,
       end of ty_value.

data: wa type ty_value.
wa = value #( name = 'Enes' role = 'Analist' ).
cl_demo_output=>display( wa ).

In diesem Codeblock wurde die wa-Definition zuvor vorgenommen und ihr Typ als ty_value festgelegt. In Fällen, in denen wir wa mit VALUE Werte zuweisen, können wir anstatt den wa-Typ nach dem VALUE-Schlüsselwort anzugeben, direkt den #-Ausdruck schreiben. Das bedeutet, dass diese wa-Definition zuvor unter Angabe ihres Typs vorgenommen wurde und wir ihr nur mit VALUE Werte zuweisen werden.

Wenn Sie es bemerkt haben, begann unser Code mit wa = value #…. Der Grund, warum er direkt mit wa = beginnt, ist, wie bereits erwähnt, dass die wa-Definition in der vorherigen Zeile vorgenommen wurde.

Verwendung von BASE mit VALUE

Mit VALUE können wir Daten innerhalb einer itab einer anderen itab zuweisen. Wir können einen itab-Typ für eine neu erstellte itab definieren. Dazu verwenden wir den BASE-Befehl.

report zae_value.

types: begin of ty_value,
         name type string,
         role type string,
       end of ty_value.

data: wa type ty_value.
data(wa2) = value #( base wa name = 'Enes' role = 'Analist' ).
cl_demo_output=>display( wa2 ).

Wir haben einen Typ namens ty_value festgelegt, der Namens- und Rolleninformationen enthält.
Wir haben den Typ unserer Struktur namens wa (auch als Arbeitsbereich bekannt) als ty_value definiert.
Wir haben eine inline wa2-Definition vorgenommen. Wir haben begonnen, sie als value # zu verwenden, aber wir haben einen Ausdruck wie base wa innerhalb der Klammern verwendet. Die Bedeutung dieses Ausdrucks ist: Definiere wa2, aber lasse seinen Typ dem von wa entsprechen. Wenn das Programm läuft, holt es die ty_value-Information, die der Typ von wa ist, anstelle von # im value #-Ausdruck und führt es so aus.

Hinzufügen mehrerer Zeilen mit VALUE

Mit VALUE kann mehr als ein Datensatz entsprechend dem Typ der itab zu einer itab hinzugefügt werden.

report zae_value.

types: begin of ty_value,
         name type string,
         role type string,
       end of ty_value.

" çok tercih edilen bir yöntem değil.
types: wa type table of ty_value with empty key.
data(itab) = value wa( ( name = 'Enes'    role = 'Analist')
                       ( name = 'Ahmet'   role = 'Developer')
                       ( name = 'Mehmet'  role = 'Müdür')
                       ( name = 'Veli'    role = 'Çaycı')
                      ).
cl_demo_output=>display( itab ).

Die am häufigsten verwendete Methode bei der Übertragung von Daten in eine itab mit Value ist die folgende. Diese Methode sollte immer verwendet werden.

report zae_value.

types: begin of ty_value,
         name type string,
         role type string,
       end of ty_value.

data: itab type table of ty_value.

itab = value #( ( name = 'Enes'    role = 'Analist')
                ( name = 'Ahmet'   role = 'Developer')
                ( name = 'Mehmet'  role = 'Müdür')
                ( name = 'Veli'    role = 'Çaycı')
               ).
cl_demo_output=>display( itab ).

Verwendung von APPEND VALUE

Daten können mit APPEND VALUE zu einer itab hinzugefügt werden.

Hinzufügen einer einzelnen Zeile zu einer itab

report zae_value.

types: begin of ty_value,
         name type string,
         role type string,
       end of ty_value.

data: itab type table of ty_value.

itab = value #( ( name = 'Enes'    role = 'Analist')
                ( name = 'Ahmet'   role = 'Developer')
                ( name = 'Mehmet'  role = 'Müdür')
                ( name = 'Veli'    role = 'Çaycı')
               ).

append value #( name = 'İsim' role = 'Role' ) to itab. " sadece 1 line ekleme işlemi

cl_demo_output=>display( itab ).

Hinzufügen mehrerer Zeilen zu einer itab

Wir können die folgende Struktur verwenden, um mehrere Zeilen zu einer itab hinzuzufügen.

report zae_value.

types: begin of ty_value,
         name type string,
         role type string,
       end of ty_value.

data: itab type table of ty_value.

itab = value #( ( name = 'Enes'    role = 'Analist')
                ( name = 'Ahmet'   role = 'Developer')
                ( name = 'Mehmet'  role = 'Müdür')
                ( name = 'Veli'    role = 'Çaycı')
               ).
" çoklu satır itab'a eklenmesi
 itab = value #( base itab ( name = 'name 1' role = 'rol 1' )
                           ( name = 'name 2' role = 'rol 2' )
               ).

cl_demo_output=>display( itab ).

Genauso wie wir möglicherweise mehrere Zeilen zu einer itab hinzufügen müssen, müssen wir möglicherweise auch Daten von einer itab in eine andere übertragen. In einem solchen Fall können wir den Code wie folgt schreiben. Die rot markierten Codes zeigen Unterschiede zu den obigen Codes.

report zae_value.

types: begin of ty_value,
         name type string,
         role type string,
       end of ty_value.

data: itab type table of ty_value.

itab = value #( ( name = 'Enes'    role = 'Analist')
                ( name = 'Ahmet'   role = 'Developer')
                ( name = 'Mehmet'  role = 'Müdür')
                ( name = 'Veli'    role = 'Çaycı')
               ).
" çoklu satırları bir itab dan diğer itab a eklenmesi
 data(itab2) = value #( base itab ( name = 'name 1' role = 'rol 1' )
                           ( name = 'name 2' role = 'rol 2' )
               ).

cl_demo_output=>display( itab2 ).

Lesen einer Tabelle mit dem [ ]-Ausdruck

report zae_value.

types: begin of ty_value,
         name type string,
         role type string,
       end of ty_value.

data: itab type table of ty_value.

itab = value #( ( name = 'Enes'    role = 'Analist')
                ( name = 'Ahmet'   role = 'Developer')
                ( name = 'Mehmet'  role = 'Müdür')
                ( name = 'Veli'    role = 'Çaycı')
               ).

data(wa_read) = itab[ name = 'Enes' ].

cl_demo_output=>display( wa_read ).

Im obigen Code lesen wir den Datensatz, dessen Name Enes ist, in wa_read (Struktur). Wir können ihn als wa_read-name aufrufen und verwenden. Wir müssen auf die Groß- und Kleinschreibung achten, wenn wir den Ausdruck 'Enes' hier schreiben. Andernfalls wird ein Dump-Fehler ausgegeben. Wenn wir Daten lesen wollen, die nicht in der Tabelle (itab) vorhanden sind, sollte unser Code während des Lesevorgangs wie folgt aussehen:

data(wa_read) = value #( itab[ name = 'Ali' ] optional ).

Es gibt keinen Datensatz namens Ali in der itab. In diesem Fall wird wa_read als leer angezeigt und es kommt nicht zu einem Dump. Wir verhindern einen Dump mit dem Schlüsselwort OPTIONAL.

Zuweisen von Werten mit Value als Standard

Wenn der Ausdruck Ali in der itab nicht gefunden werden kann und wir einen Standardwert zuweisen möchten, müssen wir unseren Code wie folgt schreiben:

report zae_value.

types: begin of ty_value,
         name type string,
         role type string,
       end of ty_value.

data: itab type table of ty_value.
data: wa_def type ty_value.

itab = value #( ( name = 'Enes'    role = 'Analist')
                ( name = 'Ahmet'   role = 'Developer')
                ( name = 'Mehmet'  role = 'Müdür')
                ( name = 'Veli'    role = 'Çaycı')
               ).

wa_def = value ty_value( name = 'Adımız' role = 'Rolümüz' ).

data(wa_read) = value #( itab[ name = 'Ali' ] default wa_def ).

cl_demo_output=>display( wa_read ).

Wir können die obigen Codes wie folgt erklären;

Wir haben Daten für die Felder „name“ und „role“ in wa_def definiert.
Ich wollte wa_read erstellen und die Zeile in der itab, deren Namensfeld Ali ist, als den Wert ziehen, den ich ihm zuweisen möchte.
Wir haben gesagt, dass, wenn unter den der wa_read zugewiesenen itab-Daten kein Wert mit dem Namen Ali vorhanden ist, die Daten in wa_def standardmäßig an wa_read übertragen werden sollen.
Wenn Sie den Code ausführen, erhalten Sie eine Ausgabe wie Name: Adımız Role: Rolümüz.
Ändern Sie den Namen Ali in der wa_read-Zeile in Enes und führen Sie das Programm aus. Dies wird Ihnen deutlich zeigen, wie der Code funktioniert.

Ressourcen

Die Ressourcen, von denen ich beim Schreiben dieses Artikels profitiert habe, sind die folgenden.

Video

YouTube-Video

Artikel